Página principal

Arduino
Registrador de temperatura en SD
DS18S20
xsetaseta@gmail.com

Este montaje utiliza la tarjeta Arduino Ethernet Shieldb como lectora de tarjetas micro SD para almacenar la temperatura de dos sensores DS18S20 colocados en un cable de dos hilos utilizando la librería OneWire.
Lo primero recomiendo leer varios tutoriales sobre el funcionamiento del sistema de comunicaciones OneWire, http://en.wikipedia.org/wiki/1-Wire .
También es fundamental ver la descripción del DS18S20, un medidor de temperaturas desde -55ºC a +125ºC y con un margen de +\- 0,5ºC.
Si queremos más resolución  podemos emplear los registros COUNT REMAIN y  COUNT PER °C, pero en este montaje no se va emplear. Si alguno desea saber como hacerlo, recomiendo la lectura del manual del CI, no es difícil su realización.
Este integrado posee la cualidad de poder alimentarse desde la propia línea de datos al poseer un condensador interno. Esto nos posibilita el poder utilizar un simple cable de dos hilos. Además podemos colocar varios DS18S20 a lo largo del cable para de esta forma poder medir diferentes temperaturas.

Esquema del circuito.


Circuito montado y funcionando.
 Los datos se almacenan en la SD y se mandan a través del puerto serie.
Como vemos en la imagen hemos colocado un led a modo de piloto para indicar si funciona la microSD y cuando podemos extraer la tarjeta microSD. Este led se coloca junto con una resistencia en serie de 1k al pin 3 del arduino.


Sonda exterior colocada en la calle mediante un cable de dos hilos.
Si queremos dejarla fija, deberiamos sellarla con silicona para impedir que se moje.


Vemos mediante la consola la temperatura de los dos sensores.
He colocado un contador para seguir cada serie de lecturas.



El programa crea un fichero de texto TEMPE.TXT donde se registra la temperatura de los distintos sensores.
Las lecturas en la SD se van acumulando.
Para conseguir temperaturas negativas he tenido que meter la sonda al frigorífico.



// Programa hecho por JUAN GALAZ
//29/12/2012
//con ideas de David Alvarez Medina para tallerarduino.wordpress.com
//y manejo de 18s20 de http://bildr.org/2011/07/ds18b20-arduino/
// Pagina sobre OneWire http://owfs.org/index.php?page=ds18s20

#include <SD.h>    
#include <OneWire.h>


File dataFile;
String temperatura;
static char valor[10];
int contador=0;
int espera=1;

OneWire ds(2); // pin utilizado para el bus Onewire

void setup()
{
  Serial.begin(9600);    // Establecemos comunicacion serie
  Serial.println("Lectura de sensores cada 10seg. y almacenar en SD");
  Serial.println("Iniciando tarjeta SD");    // Texto informativo
  pinMode(3, OUTPUT); //piloto para sacar la SD
  
  pinMode(4, OUTPUT);    // Declaramos el pin ChipSelect como salida
  if(!SD.begin(4)){    // Si no hay tarjeta o esta mal... 
    Serial.println("Tarjeta erronea o no insertada");    // Texto informativo
    return;
  }
  Serial.println("Tarjeta OK");    // Texto informativo
}

void loop()
{
  digitalWrite(3, LOW);
  dataFile=SD.open("tempe.txt", FILE_WRITE);    // Creamos archivo de texto
  if(dataFile)
   { 
    if(contador==0) 
      {
        dataFile.println("Inicio lecturas");
        contador++;
      }
        
    if(0==getTemp())
      {
        dataFile.print(contador);
        Serial.print(contador);
        dataFile.println(",");
        Serial.println(" , Fin de sensores");
        espera=8000;
        contador++;
      }
      else
      {       
       dataFile.print(temperatura);
       dataFile.print(",");
       Serial.print(temperatura);
       Serial.print(", "); 
       espera=1;   
      }
    dataFile.close();    // Cerramos la escritura dentro del archivo    
   }
   else
   {
    Serial.println("Error write SD ");   
   }
   
  digitalWrite(3, HIGH);
  delay(espera);    // Espera entre lecturas
}


int getTemp()
{

byte data[12];
byte addr[8];
int i;
byte MSB;
byte LSB;

  if ( !ds.search(addr)) 
    {
      ds.reset_search();
      return 0;
    }

  if ( OneWire::crc8( addr, 7) != addr[7])
    {
      Serial.println("CRC is not valid!");
      return -1;
    }

  if ( addr[0] != 0x10 && addr[0] != 0x28)
    {
      Serial.print("Device is not recognized");
      return -1;
    }

  ds.reset();
  ds.select(addr);
  ds.write(0x44,1); // start conversion, with parasite power on at the end
  delay(1000);  // espera para que carge la tension el IC

  byte present = ds.reset();
  ds.select(addr);
  ds.write(0xBE); // Read Scratchpad

  for ( i = 0; i < 9; i++) 
      { // we need 9 bytes
        data[i] = ds.read();
      }

    MSB = data[1];
    LSB = data[0];

    temperatura="";
	i=LSB>>1;
    if(MSB & 128)
      {
       temperatura=temperatura + "-";
	i=128-i;
      }
      else
      {
        temperatura=temperatura + "+";
      }    
    
    sprintf(valor, "%i", i);
    temperatura=temperatura+valor;
    
    if(LSB & 1)
        temperatura=temperatura + ".5";
      else
        temperatura=temperatura + ".0";
 
  return 1;
}


Programa del arduino.
Como se puede observar el código para determinar la temperatura es un tanto particular, es debido a que no quiero utilizar float.


Un saludo.
JUAN GALAZ

Bibliografía:
    http://en.wikipedia.org/wiki/1-Wire .
    tallerarduino.wordpress.com David Alvarez Medina
    http://bildr.org/2011/07/ds18b20-arduino/
    http://owfs.org/index.php?page=ds18s20

www.000webhost.com